Windev21 Aulas,Estudos e Desenvolvimento: 06/29/16

quarta-feira, 29 de junho de 2016

WM Imprimir Mobile - Print From Mobile

Forum.pcsoft.fr/fr-FR/pcsoft.br.windev/1398-imprimir-mobile-print-from-mobile/read.awp

Posté le 28 juin 2016 - 23:18

1 - Procedimento para Conectar/Desconectar
1 - Procedimiento para Conectar/Desconectar
1 - Procedure to Connect and Disconnect

// Summary: Conectar/Desconectar con la Impresora
// Syntax:
//[
 <Result> = ] PRINT_ConnectarDesconectar 
(<s_nombreDispositivo> is string [, <b_conectarDesconectar> 
is boolean [, <s_socketNombre> is string]])
//
// Parameters:
// s_nombreDispositivo (ANSI string): Nombre del Dispositivo Bluetooth conectado al Telefono
// b_conectarDesconectar (boolean - default value=1): Para Conectar(true) o Desconectar(false)
// s_socketNombre (ANSI string - default value=""): Nombre del Socket para la Desconexion
// Return Value:
//  Unspecified Type: //  String
//
// For instance:
// Indicate an example.
//
Procedure PRINT_ConnectarDesconectar(s_nombreDispositivo is string,b_conectarDesconectar is boolean = True , s_socketNombre is string = "")
WHEN EXCEPTION IN
 IF b_conectarDesconectar = True THEN
  s_listaDeDispositivos is string
  s_dispositivo is string //Para el For Each
  s_idDispositivo is string
  s_mACAddress is string //Este es la informacion que nos interesa
  s_listaDeDispositivos = BTListDevice(btSimpleList) //Lista todos los dispositivos Conectados
  b_conectado is boolean = False
  FOR EACH STRING s_dispositivo OF s_listaDeDispositivos SEPARATED by CR
   s_idDispositivo = ExtractString(s_dispositivo, 1)
   s_mACAddress = ExtractString(s_dispositivo, 2)
   IF s_nombreDispositivo = BTInfoDevice(s_idDispositivo, btName) THEN //Si encontramos el Dispositivo que queremos, Conectamos
    b_conectado = True
    BREAK
   END
  END
  IF b_conectado THEN
   s_sock is string
   s_sock = "SOCK"+s_mACAddress
   IF NOT SocketConnectBluetooth(s_sock,"SerialPortServiceClass_UUID",s_mACAddress,15000) THEN
    RESULT "No se Pudo Conectar a la Impresora " + ErrorInfo()
   ELSE
    SocketChangeTransmissionMode(s_sock,SocketEndTag,CRLF) //Cambiar a modo Fin de Texto para el envio de String
    RESULT s_sock //en caso de Conexion retornamos el SOCK
   END
  ELSE
   RESULT "No Se Encontro Dispositivo"
  END
 ELSE
  IF SocketClose(s_socketNombre) THEN
   RESULT ""
  ELSE
   RESULT "Error "+ErrorInfo()
  END
 END
DO
 RESULT "Error Exception "+ExceptionInfo()
END

2 - Procedimento para Enviar Impresão
2 - Procedimiento para Enviar la Impresion
2 - Procedure to Send to Printer

// Summary: Envia Impresion para la Impresora
// Syntax:
//[ <Result> = ] PRINT_Imprimir (<s_nombreSocket> is string, <s_texto> is string)
//
// Parameters:
// s_nombreSocket (ANSI string): Nombre del Socket Creado por >> PRINT_ConnectarDesconectar <<
// s_texto (ANSI string): Texto a Imprimir
// Return Value:
//  boolean: // True = Imprimio, False = No Imprimio
//
// For instance:
// Indicate an example.
//
Procedure PRINT_Imprimir(s_nombreSocket is string , s_texto is string)
IF NOT SocketWrite(s_nombreSocket,s_texto) THEN
 Info("Error al Enviar Impresion"+ErrorInfo())
 RESULT False
ELSE
 RESULT True
END

Exemplo de como utilizar
Ejemplo de como utilizar
Example of using

s_socketImpresora is string
s_socketImpresora = PRINT_ConnectarDesconectar("MPD2",True,"")
IF Left(s_socketImpresora,4) = "SOCK" THEN //Conectado
 PRINT_Imprimir(s_socketImpresora,"HOLA MUNDO Con Windev Mobile")
 PRINT_ConnectarDesconectar("",False,s_socketImpresora)
ELSE
 Info(s_socketImpresora)
END

Bom Proveito

--
Atte. Willian Fernando

Vous devez être connecté pour évaluer ce message

BOLLER ADRIANO

Membre enregistré
1 866 messages
Popularité : +89 (91 votes)

Posté le 29 juin 2016 - 00:47

Parabéns Willian!

--
Adriano José Boller
______________________________________________
Consultor e Representante Oficial da
PcSoft no Brasil
+55 (41) 9949 1800
adrianoboller@gmail.com
skype: adrianoboller
http://wxinformatica.com.br/

Willian Fernando

Membre enregistré
59 messages
Popularité : +5 (5 votes)

Posté le 29 juin 2016 - 16:55

A modo de correção
Correccion

no primeiro metodo
en el primer metodo
In the first method

IF SocketClose(s_socketNombre) THEN
RESULT ""
ELSE
RESULT "Error "+ErrorInfo()
END

deve estar assim
debe estar asi
You must be well

SocketClose(s_socketNombre)
RESULT ""

o metodo SocketClose http://doc.pcsoft.fr/en-US/?3070015&name=SocketClose não retorna valores
el metodo SocketClose http://doc.pcsoft.fr/en-US/?3070015&name=SocketClose no devuelve valores
the method SocketClose http://doc.pcsoft.fr/en-US/?3070015&name=SocketClos does not return values

Páginas

quarta-feira, 29 de junho de 2016

WM Imprimir Mobile - Print From Mobile

Windev Mobile - 67/... Painel_Dispositivos